利用單片機(jī)（或單板機(jī)）奏樂大概是無線電愛好者感興趣的問題之一。本文從單片機(jī)的基本發(fā)間實(shí)驗(yàn)出發(fā)，談?wù)?strong>音樂程序的設(shè)計(jì)原理，并給出具體實(shí)例，以供參考。

單片機(jī)的基本發(fā)音實(shí)驗(yàn)

我們知道，聲音的頻譜范圍約在幾十到幾千赫茲，若能利用程序來控制單處機(jī)某個(gè)口線的“高”電平或低電平，則在該口線上就能產(chǎn)生一定頻率的矩形波，接上喇叭就能發(fā)出一定頻率的聲音，若再利用延時(shí)程序控制“高”“低”電平的持續(xù)時(shí)間，就能改變輸出頻率，從而改變音調(diào)。

例如，要產(chǎn)生200Hz的音頻信號(hào)，按圖1接入喇叭（若屬臨時(shí)實(shí)驗(yàn)，也可將喇叭直接接在P1口線上），實(shí)驗(yàn)程序?yàn)椋?/p>

其中子程序DEL為延時(shí)子程序，當(dāng)R3為1時(shí)，延時(shí)時(shí)間約為20us，R3中存放延時(shí)常數(shù)，對(duì)200HZ音頻，其周期為1/200秒，即5ms。這樣，當(dāng)P1.4的高電平或低電平的持續(xù)時(shí)間為2.5ms，即R3的時(shí)間常數(shù)取2500/20=125(7DH)時(shí)，就能發(fā)出200HZ的音調(diào)。將上述程序鍵入學(xué)習(xí)機(jī)，并持續(xù)修改R3的常數(shù)能感到音調(diào)的變化。樂曲中，每一音符對(duì)應(yīng)著確定的頻率，表1給出C調(diào)時(shí)各音符頻率及其對(duì)應(yīng)的時(shí)間常數(shù)。讀者能根據(jù)表1所供給的常數(shù)，將其16進(jìn)制代碼送入R3，反復(fù)練習(xí)體會(huì)。根據(jù)表1能奏出音符。僅這還不夠，要準(zhǔn)確奏出一首曲子，必須準(zhǔn)確地控制樂曲節(jié)奏，即一音符的持續(xù)時(shí)間。

音符的節(jié)拍我們能用定時(shí)器T0來控制，送入不一樣的初值，就能產(chǎn)生不一樣的定時(shí)時(shí)間。便如某歌曲的節(jié)奏為每分鐘94拍，即一拍為0.64秒。其它節(jié)拍與時(shí)間的對(duì)應(yīng)關(guān)系見表2。

但時(shí)，由于T0的最大定時(shí)時(shí)間只能為131毫秒，因此不可能直接用改變T0的時(shí)間初值來實(shí)現(xiàn)不一樣節(jié)拍。我們能用T0來產(chǎn)生10毫秒的時(shí)間基準(zhǔn)，然后設(shè)置一個(gè)中斷計(jì)數(shù)器，通過判別中斷計(jì)數(shù)器的值來控制節(jié)拍時(shí)間的長短。表2中也給出了各種節(jié)拍所對(duì)應(yīng)的時(shí)間常數(shù)。例如對(duì)1/4拍音符，定時(shí)時(shí)間為0.16秒，對(duì)應(yīng)的時(shí)間常數(shù)為16（即10H）；對(duì)3拍音符，定時(shí)時(shí)間為1.92秒，對(duì)應(yīng)時(shí)間長數(shù)為192（即C0H）。

我們將每一音符的時(shí)間常數(shù)和其對(duì)應(yīng)的節(jié)拍常數(shù)作為一組，按次序?qū)非械乃谐?shù)排列成一個(gè)表，然后由查表程序依次取出，產(chǎn)生音符并控制節(jié)奏，就能實(shí)現(xiàn)演奏效果。此外，結(jié)束符和體止符能分別用代碼00H和FFH來表示，若查表結(jié)果為00H，則表示曲子終了；若查表結(jié)果為FFH，則產(chǎn)生對(duì)應(yīng)的停頓效果。為了產(chǎn)生手彈的節(jié)奏感，在某些音符（例如兩個(gè)相同音符）音插入一個(gè)時(shí)間單位的頻率略有不一樣的音符。

下面給出程序序清單，可直接在TD-III型學(xué)習(xí)機(jī)上演奏，對(duì)其它不一樣型號(hào)的學(xué)習(xí)機(jī)，只需對(duì)應(yīng)地改變一下地址即可。本程序演奏的是民歌“八月桂花遍地開”，C調(diào)，節(jié)奏為94拍/分。讀者也能自行找出一首歌，按表1和表2給定的常數(shù)，將樂曲翻譯成碼表輸入機(jī)器，而程序不變。本實(shí)驗(yàn)辦法簡便，即使不懂音樂的人，將一首陌生的曲子翻譯成代碼也是易事，和著機(jī)器的演奏學(xué)唱一首歌曲，其趣味無窮。

程序清單（略，請(qǐng)參看源程序的說明）。

程序框圖如圖2所示。

本課由單片機(jī)教程網(wǎng)提供,有問題指出.

硬件連接說明:

隨便找一個(gè)仿真機(jī)或者什么單片機(jī)實(shí)驗(yàn)板，只要能工作的就行，將程序輸入，運(yùn)行，然后找個(gè)音箱（你計(jì)算機(jī)旁邊應(yīng)當(dāng)就有一對(duì)吧）撥出插頭，插頭的前端接在P1。0上，后面部分找根線接單片機(jī)的地，就應(yīng)當(dāng)有聲了，然后怎么改進(jìn)硬件連接就是你的事了。。。。

音樂程序匯編代碼代碼1 -------------VoICe.asm--------------------------

ORG 0000H
LJMP START
ORG 000BH
INC 20H ;中斷服務(wù),中斷計(jì)數(shù)器加1
MOV TH0,#0D8H
MOV TL0,#0EFH ;12M晶振，形成10毫秒中斷
RETI
START:
MOV SP,#50H
MOV TH0,#0D8H
MOV TL0,#0EFH
MOV TMOD,#01H
MOV IE,#82H
MUSIC0:
NOP
MOV DPTR,#DAT ;表頭地址送DPTR
MOV 20H,#00H ;中斷計(jì)數(shù)器清0
MOV B,#00H ;表序號(hào)清0
MUSIC1:
NOP
CLR A
MOVC A,@A+DPTR ;查表取代碼
JZ END0 ;是00H,則結(jié)束
CJNE A,#0FFH,MUSIC5
LJMP MUSIC3
MUSIC5:
NOP
MOV R6,A
INC DPTR
MOV A,B
MOVC A,@A+DPTR ;取節(jié)拍代碼送R7
MOV R7,A
SETB TR0 ;啟動(dòng)計(jì)數(shù)
MUSIC2:
NOP
CPL P1.0
MOV A,R6
MOV R3,A
LCALL DEL
MOV A,R7
CJNE A,20H,MUSIC2 ;中斷計(jì)數(shù)器(20H)=R7否?
;不等,則繼續(xù)循環(huán)
MOV 20H,#00H ;等于,則取下一代碼
INC DPTR
; INC B
LJMP MUSIC1
MUSIC3:
NOP
CLR TR0 ;休止100毫秒
MOV R2,#0DH
MUSIC4:
NOP
MOV R3,#0FFH
LCALL DEL
DJNZ R2,MUSIC4
INC DPTR
LJMP MUSIC1
END0:
NOP
MOV R2,#64H ;歌曲結(jié)束,延時(shí)1秒后繼續(xù)
MUSIC6:
MOV R3,#00H
LCALL DEL
DJNZ R2,MUSIC6
LJMP MUSIC0
DEL:
NOP
DEL3:
MOV R4,#02H
DEL4:
NOP
DJNZ R4,DEL4
NOP
DJNZ R3,DEL3
RET
NOP

DAT:
db 26h,20h,20h,20h,20h,20h,26h,10h,20h,10h,20h,80h,26h,20h,30h,20h
db 30h,20h,39h,10h,30h,10h,30h,80h,26h,20h,20h,20h,20h,20h,1ch,20h
db 20h,80h,2bh,20h,26h,20h,20h,20h,2bh,10h,26h,10h,2bh,80h,26h,20h
db 30h,20h,30h,20h,39h,10h,26h,10h,26h,60h,40h,10h,39h,10h,26h,20h
db 30h,20h,30h,20h,39h,10h,26h,10h,26h,80h,26h,20h,2bh,10h,2bh,10h
db 2bh,20h,30h,10h,39h,10h,26h,10h,2bh,10h,2bh,20h,2bh,40h,40h,20h
db 20h,10h,20h,10h,2bh,10h,26h,30h,30h,80h,18h,20h,18h,20h,26h,20h
db 20h,20h,20h,40h,26h,20h,2bh,20h,30h,20h,30h,20h,1ch,20h,20h,20h
db 20h,80h,1ch,20h,1ch,20h,1ch,20h,30h,20h,30h,60h,39h,10h,30h,10h
db 20h,20h,2bh,10h,26h,10h,2bh,10h,26h,10h,26h,10h,2bh,10h,2bh,80h
db 18h,20h,18h,20h,26h,20h,20h,20h,20h,60h,26h,10h,2bh,20h,30h,20h
db 30h,20h,1ch,20h,20h,20h,20h,80h,26h,20h,30h,10h,30h,10h,30h,20h
db 39h,20h,26h,10h,2bh,10h,2bh,20h,2bh,40h,40h,10h,40h,10h,20h,10h
db 20h,10h,2bh,10h,26h,30h,30h,80h,00H